BibTeX, biblatex and biber ⇒ Three authors before et al.

[Matias]

Hi guys.

I use LyX 1.6 and JabRef 2.5.

I use a bib style file called vancouver.bst.

It lists 6 authors before et al., and I want it to list 3. Is this possible?

I upload the .bst file as an attachment. It's located inside vancouver.zip.

Edit: Here is the part in the code I think controls this.

Code: Select all

FUNCTION {format.names}
{ 'bibinfo :=
  duplicate$ empty$ 'skip$ {
  "." ". " find.replace 's :=
  "" 't :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { s nameptr
      "{vv~}{ll}{ f{}}{ jj}"
      format.name$
      remove.dots
      bibinfo bibinfo.check
      't :=
      nameptr #1 >
        {
          nameptr #6
          #1 + =
          numnames #6
          > and
            { "others" 't :=
              #1 'namesleft := }
            'skip$
          if$
          namesleft #1 >
            { ", " * t * }
            {
              "," *
              s nameptr "{ll}" format.name$ duplicate$ "others" =
                { 't := }
                { pop$ }
              if$
              t "others" =
                {
                  " " * bbl.etal *
                }
                { " " * t * }
              if$
            }
          if$
        }
        't
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
  } if$
}

[olofos]

It should work to change the lines

Code: Select all

          nameptr #6
          #1 + =
          numnames #6
          > and

to

Code: Select all

          nameptr #3
          #1 + =
          numnames #3
          > and

Don't forget to rename the file before making changes to it.

[Matias]

Thank you, that seems to work.